u = 2.5cm;

def Bstrek (expr a, b) =
  pickup pencircle scaled 0.8pt;
  draw a--b dashed evenly withcolor blue;
enddef;

def Bpunkt (expr a) =
  pickup pencircle scaled 3pt;
  draw a withcolor blue;
enddef;

def Lpenn =
  pickup pencircle scaled 1.2pt;
enddef;

def Lstrek(expr a, b, c, d) =
  Lpenn;
  draw a .. controls b and c .. d withcolor red;
enddef;

def Lrett(expr a, b) =
  Lpenn;
  draw a -- b withcolor red;
enddef;

def Lpunkt (expr a) =
  pickup pencircle scaled 4pt;
  draw a withcolor red;
enddef;

def Bezier (expr a, b, c, d) =
  Bstrek(a,b);  Bstrek(c,d);
  Bpunkt(b);  Bpunkt(c);

  Lstrek(a,b,c,d);
  Lpunkt(a);  Lpunkt(d);
enddef;

beginfig(1);
  Bezier((0,0), (0,1u), (1u,1u), (1u,0));
endfig;

beginfig(2);
  Bezier((0,0), (0,1u), (1u,0), (1u,1u));
endfig;

beginfig(3);
  Bezier((0.4u,0.5u), (0,0.5u), (1u,1u), (0.9u,0.5u));
endfig;


def LagHjorne =
  z100 = (0,-0.2u);  z101 = (0,0.3u);
  z105 = (0.5u,0.8u);  z106 = (1u,1u);

  Lpenn;
  Lrett(z100,z101);  Lrett(z105,z106);

  z102 = 1.5[z100,z101];  z103 = 2.1[z100,z101];  z104 = 2.6[z100,z101];
  z107 = 1.5[z106,z105];  z108 = 2.1[z106,z105];  z109 = 2.6[z106,z105];
enddef;

beginfig(4);
  LagHjorne;
endfig;

beginfig(5);
  LagHjorne;
  Bpunkt(z102);  Bpunkt(z107);
  Bstrek(z101,z102);  Bstrek(z105,z107);
  Lstrek(z101,z102,z107,z105);
endfig;

beginfig(6);
  LagHjorne;
  Bpunkt(z103);  Bpunkt(z108);
  Bstrek(z101,z103);  Bstrek(z105,z108);
  Lstrek(z101,z103,z108,z105);
endfig;

beginfig(7);
  LagHjorne;
  Bpunkt(z104);  Bpunkt(z109);
  Bstrek(z101,z104);  Bstrek(z105,z109);
  Lstrek(z101,z104,z109,z105);
endfig;


def TegnBasis =
  z200 = origin;  z201 = (0,1u);  z202 = (0.8u,0.9u);  z203 = (1u,0);
  z204 = 0.5[z200,z201];  z205 = 0.5[z202,z203];  z206 = 0.5[z201,z202];
  z207 = 0.5[z204,z206];  z208 = 0.5[z206,z205];  z209 = 0.5[z207,z208];
  Bezier(z200, z201, z202, z203);
enddef;

def Gstrek (expr a, b) =
  pickup pencircle scaled 0.6pt;
  draw a -- b;
enddef;

def TegnLinjeI =
  Gstrek(z201,z202);
  Gstrek(z204,z206);  Gstrek(z206,z205);
enddef;

def TegnLinjeJ =
  Gstrek(z207,z208);
  pickup pencircle scaled 2.5pt;  drawdot z209;
enddef;

beginfig(8);
  TegnBasis;
endfig;

beginfig(9);
  TegnBasis;  TegnLinjeI;
endfig;
 
beginfig(10);
  TegnBasis;  TegnLinjeI;  TegnLinjeJ;
endfig;
 
def TegnBasisX =
  z200 = origin;  z201 = (0,1u);  z202 = (0.8u,0.9u);  z203 = (1u,0);
  z204 = 0.25[z200,z201];  z205 = 0.25[z202,z203];  z206 = 0.25[z201,z202];
  z207 = 0.25[z204,z206];  z208 = 0.25[z206,z205];  z209 = 0.25[z207,z208];
  Bezier(z200, z201, z202, z203);
enddef;

beginfig(11);
  TegnBasisX;
endfig;

beginfig(12);
  TegnBasisX;  TegnLinjeI;
endfig;
 
beginfig(13);
  TegnBasisX;  TegnLinjeI;  TegnLinjeJ;
endfig;
 
end